Merge branch 'feature/cmake-default-include-directories' into 'master'

Provide a cmake utility dune_default_include_directories

Closes #332

See merge request !1355

CHANGELOG.md

@@ -7,6 +7,13 @@ SPDX-License-Identifier: LicenseRef-GPL-2.0-only-with-DUNE-exception
 
 ## Build system: Changelog
 
+
+- Change the way include directories are set in dune projects. OLD behavior: use `include_directories`
+  in `dune_project` to set include dirs for the current project. NEW behavior: Provide a utility
+  `dune_default_include_directories` to set include dirs on targets manually. Which behavior to
+  activate can be decided in each module by using the new dune policy `DP_DEFAULT_INCLUDE_DIRS`, which can be set
+  to `OLD` or `NEW` correspondingly.
+
 - The CMake function `dune_target_enable_all_packages` can now handle Interface libraries too.
 
 ## C++: Changelog

CMakeLists.txt

@@ -15,12 +15,18 @@ list(APPEND CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake/modules)
 #include the dune macros
 include(DuneMacros)
 
+# deactivate global include-directories for dune-common
+dune_policy(SET DP_DEFAULT_INCLUDE_DIRS NEW)
+
 # start a dune project with information from dune.module
 dune_project()
 
 # Create a target for dune-common with a Dune::Common alias
 dune_add_library(dunecommon EXPORT_NAME Common NAMESPACE Dune::)
 
+# set include directories for dunecommon library
+dune_default_include_directories(dunecommon PUBLIC)
+
 # minimal c++ standard required
 target_compile_features(dunecommon PUBLIC cxx_std_20)
 

cmake/modules/CMakeLists.txt

@@ -21,6 +21,7 @@ install(FILES
   DuneAddLibrary.cmake
   DuneAddPybind11Module.cmake
   DuneCommonMacros.cmake
+  DuneDefaultIncludeDirectories.cmake
   DuneDoc.cmake
   DuneDoxygen.cmake
   DuneEnableAllPackages.cmake

cmake/modules/DuneAddLibrary.cmake

@@ -181,6 +181,9 @@ function(dune_add_library_normal _name)
   # Link with specified libraries from parameter ADD_LIBS
   target_link_libraries(${_name} PUBLIC "${ARG_LINK_LIBRARIES}")
 
+  # Activate warnings from all imported targets we link against
+  set_target_properties(${_name} PROPERTIES NO_SYSTEM_FROM_IMPORTED TRUE)
+
   # Set target options from COMPILE_FLAGS
   target_compile_options(${_name} PUBLIC "${ARG_COMPILE_OPTIONS}")
 
@@ -250,6 +253,9 @@ function(dune_add_library_interface _name)
   # Link with specified libraries from parameter LINK_LIBRARIES
   target_link_libraries(${_name} INTERFACE "${ARG_LINK_LIBRARIES}")
 
+  # Activate warnings from all imported targets we link against
+  set_target_properties(${_name} PROPERTIES NO_SYSTEM_FROM_IMPORTED TRUE)
+
   # Set target options from COMPILE_FLAGS
   target_compile_options(${_name} INTERFACE "${ARG_COMPILE_OPTIONS}")
 

cmake/modules/DuneDefaultIncludeDirectories.cmake

+# SPDX-FileCopyrightInfo: Copyright © DUNE Project contributors, see file LICENSE.md in module root
+# SPDX-License-Identifier: LicenseRef-GPL-2.0-only-with-DUNE-exception
+
+#[=======================================================================[.rst:
+DuneDefaultIncludeDirectories
+-----------------------------
+
+Add the default include directories to a target.
+
+.. cmake:command:: dune_default_include_directories
+
+  Add the source and build directory the the targets include directories
+  in the build-interface and the corresponding installed include dir in
+  the install-interface.
+
+  .. code-block:: cmake
+
+    dune_default_include_directories(<target> [PRIVATE|PUBLIC|INTERFACE])
+
+#]=======================================================================]
+include_guard(GLOBAL)
+
+function(dune_default_include_directories _target _scope)
+  target_include_directories(${_target} ${_scope}
+    $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}>
+    $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}>          # config.h
+    $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include>  # <module>-config.hh
+    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
+  if(NOT _scope STREQUAL "INTERFACE")
+    target_include_directories(${_target} PRIVATE
+      $<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include_private>) # <module>-config-private.hh
+  endif()
+endfunction(dune_default_include_directories)
\ No newline at end of file

cmake/modules/DuneMacros.cmake

@@ -35,6 +35,7 @@ enable_language(C) # Enable C to skip CXX bindings for some tests.
 set(THREADS_PREFER_PTHREAD_FLAG TRUE CACHE BOOL "Prefer -pthread compiler and linker flag")
 
 include(DuneAddLibrary)
+include(DuneDefaultIncludeDirectories)
 include(DuneEnableAllPackages)
 include(DuneExecuteProcess)
 include(DuneModuleDependencies)

cmake/modules/DuneProject.cmake

@@ -57,6 +57,9 @@ include(GNUInstallDirs)
 include(Headercheck)
 include(OverloadCompilerFlags)
 
+include(DunePolicy)
+dune_define_policy(DP_DEFAULT_INCLUDE_DIRS dune-common 2.12
+  "OLD behavior: Use global include_directories. NEW behavior: Include directories must be set on a module library target and are not set globally anymore.")
 
 # Macro that should be called near the beginning of the top level CMakeLists.txt.
 # Namely it sets up the module, defines basic variables and manages
@@ -163,12 +166,14 @@ macro(dune_project)
   include(CheckCXXFeatures)
 
   # set include path and link path for the current project.
-  include_directories("${PROJECT_BINARY_DIR}")
-  include_directories("${PROJECT_SOURCE_DIR}")
-  include_directories("${CMAKE_CURRENT_BINARY_DIR}")
-  include_directories("${CMAKE_CURRENT_SOURCE_DIR}")
-  include_directories("${CMAKE_CURRENT_BINARY_DIR}/include")
-  include_directories("${CMAKE_CURRENT_BINARY_DIR}/include_private")
+  dune_policy(GET DP_DEFAULT_INCLUDE_DIRS _include_policy)
+  if(_include_policy STREQUAL "OLD")
+    include_directories("${PROJECT_SOURCE_DIR}")
+    include_directories("${PROJECT_BINARY_DIR}")
+    include_directories("${PROJECT_BINARY_DIR}/include")
+    include_directories("${PROJECT_BINARY_DIR}/include_private")
+  endif()
+  unset(_include_policy)
   add_definitions(-DHAVE_CONFIG_H)
 
   # Create custom target for building the documentation

doc/buildsystem/dune-common.rst

@@ -208,7 +208,9 @@ not want to see any policy warnings and just stick with the defaults, the global
 Policies Introduced by Dune 2.10
 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
 
-Here we will list and explain the introduced policies.
+``DP_DEFAULT_INCLUDE_DIRS`` (dune-common, set to NEW by default in version 2.12)
+    *OLD behavior:* Set global ``include_directories`` when creating a new ``dune_project``.
+    *NEW behavior:* Include directories must be set on a module library targets and are not set globally anymore.
 
 
 .. _faq: